Hier sind:
Inhalt splitstring klartext replaceinstring strip uppercase lowercase ascisalat fuellli fuellre fuellnumre abstand abstandnum
Inhalt von String formatting tools vom. 28.03.98
Übersicht
-- String formatting tools
on splitString darst,delim
on klartext dString,dTeil
-- strips dString of any ocurrence of dTeil
-- entfernt jedes Vorkommen von dTeil in dString
on replaceInString dChunk,nono,anstatt
-- replace any ocurrence of nono in dChunk by anstatt
-- ersetze in dChunk jedes Vorkommen von nono durch anstatt
on strip txt
-- Clean text input from leading, trailing spaces or RETURN
-- Putze Texteingaben,
on Uppercase zeile
--diese Routine sorgt für GRO?SCHREIBUNG!
on Lowercase zeile
--diese Routine sorgt für kleinschreibung
on asciSalat lang
-- return a String of lang chars length with random ascii
-- erzeuge ziemlich zufälligen String
on fuellLi n,lang
-- returns a string of lang chars length that contains n left aligned
-- gib String auf lang stellen linksbuendig
on fuellRe n,lang
-- returns a string of lang chars length that contains n right aligned
-- gib String auf lang stellen rechtsbuendig
on fuellNumRe n,lang
-- returns a string of lang chars length that contains the integer n with leading 0
-- gib Ziffer auf lang stellen rechtsbuendig
on Abstand lang
-- gib (lang) Zeichen Spaces
on AbstandNum lang
-- gib (lang) Zeichen "0"
Inhalt top Callers
on splitString darst,delim
if voidp(delim) then set delim="_"
-- gibt eine Liste von teilen eines Strings oder symbol zwischen delim
set erg=[]
--
if symbolP(darst) then set darst=string(darst)
if voidP(darst) then return erg
set da=offset(delim,darst)
repeat while da > 0
set teil=chars(darst,1,da-1)
set darst=chars(darst,da+1,the number of chars in darst)
set da=offset(delim,darst)
append erg,teil
end repeat
if the number of chars in darst > 0 then append erg,darst
return erg
end
Inhalt top Callers
on klartext dString,dTeil
-- strips dString of any ocurrence of dTeil
-- entfernt jedes Vorkommen von dTeil in dString
set da=offset(dTeil, dString)
set dTeil.len=the number of chars in dTeil
set dString.len=the number of chars in dString
repeat while da > 0
set dString=chars(dString,1,da-1) & chars(dString,da + dTeil.len,dString.len)
set da=offset(dTeil, dString)
set dString.len=the number of chars in dString
end repeat
return dString
end
Inhalt top Callers
on replaceInString dChunk,nono,anstatt
-- replace any ocurrence of nono in dChunk by anstatt
-- ersetze in dChunk jedes Vorkommen von nono durch anstatt
set nono.len = the number of chars in nono
set dChunk.len = the number of chars in dChunk
set da=offset(nono,dChunk)
repeat while da > 0
set dChunk= chars(dChunk,1,da-1) & anstatt & chars(dChunk,da + nono.len,dChunk.len)
set da=offset(nono,dChunk)
end repeat
return dChunk
end
Inhalt top Callers
on strip txt
-- Clean text input from leading, trailing spaces or RETURN
-- Putze Texteingaben,
if not stringP(txt) then exit
-- Return hinten muss weg
set lang = the number of chars in txt
if char lang of txt = RETURN then delete char lang of txt
-- leere am Anfang weg
set lang = the number of chars in txt
repeat with rum = 1 to lang
if char rum of txt = " " then delete char rum of txt
else exit repeat
end repeat
-- leere am Ende weg
set lang = the number of chars in txt
repeat with rum = lang down to 1
if char rum of txt = " " then delete char rum of txt
else exit repeat
end repeat
return txt
end
Inhalt top Callers
on Uppercase zeile
--diese Routine sorgt für GRO?SCHREIBUNG!
put "" into zille
repeat with j=1 to the number of chars in zeile
set n=chartonum(chars(zeile,j,j))
if n>=97 and n<=122 then set n=n-32
put numtochar(n) after zille
end repeat
return zille
end
Inhalt top Callers
on Lowercase zeile
--diese Routine sorgt für kleinschreibung
put "" into zille
repeat with j=1 to the number of chars in zeile
set n=chartonum(chars(zeile,j,j))
if n>=65 and n<=90 then set n=n+32
put numtochar(n) after zille
end repeat
return zille
end
Inhalt top Callers
on asciSalat lang
-- return a String of lang chars length with random ascii
-- erzeuge ziemlich zufälligen String
set erg=""
repeat with rum=1 to lang
set teil=numToChar(random(26)+64)
set erg=erg & teil
end repeat
return erg
end
Inhalt top Callers
on fuellLi n,lang
-- returns a string of lang chars length that contains n left aligned
-- gib String auf lang stellen linksbuendig
if not StringP(n) then set n="n/a"
set viel=the number of chars in n
if viel > lang then set n=chars(n,1,lang)
set erg=n & abstand(lang - (the number of chars in n))
return erg
end
Inhalt top Callers
on fuellRe n,lang
-- returns a string of lang chars length that contains n right aligned
-- gib String auf lang stellen rechtsbuendig
if not StringP(n) then set n="n/a"
set viel=the number of chars in n
if viel > lang then set n=chars(n,1,lang)
set erg=abstand(lang - (the number of chars in n)) & n
return erg
end
Inhalt top Callers
on fuellNumRe n,lang
-- returns a string of lang chars length that contains the integer n with leading 0
-- gib Ziffer auf lang stellen rechtsbuendig
if not StringP(n) then set n=String(n)
set viel=the number of chars in n
if viel > lang then set n=chars(n,1,lang)
set erg=abstandNum(lang - (the number of chars in n)) & n
return erg
end
Inhalt top Callers
on Abstand lang
-- gib (lang) Zeichen Spaces
set erg=""
if voidP(lang) then set lang =0
repeat with rum=1 to lang
set erg=erg & " "
end repeat
return erg
end
Inhalt top Callers
on AbstandNum lang
-- gib (lang) Zeichen "0"
set erg=""
if voidP(lang) then set lang =0
repeat with rum=1 to lang
set erg=erg & "0"
end repeat
return erg
end
-- /IHV
HTML created by dp tiny script documenting xtra v0.2 28.03.98 pageID=StringForm